SELECT - sort_key

Syntax

... ORDER BY { {PRIMARY KEY}
             | { {col1|a1} [ASCENDING|DESCENDING]
                 {col2|a2} [ASCENDING|DESCENDING] ...}
             | (column_syntax) } ... .

Alternatives:

1. ... ORDER BY PRIMARY KEY

2. ... ORDER BY {col1|a1} [ASCENDING|DESCENDING]
               {col2|a2} [ASCENDING|DESCENDING] ...

3. ... ORDER BY (column_syntax)

Effect:

The addition ORDER BY sorts a multiline resulting set by the content of the specified column. The order of the rows in the result set refers to all columns that are not listed after ORDER BY, is undefined, and can be different in repeated executions of the same SELECT statement.

If the addition FOR ALL ENTRIES is used in the WHERE condition, ORDER BY can only be used with the addition PRIMARY KEY. The addition ORDER BY cannot be used with the addition SINGLE.

Note:

If a sorted resulting set is assigned to a sorted internal table, the internal table is sorted again according to the sorting instructions.

Alternative 1

... ORDER BY PRIMARY KEY

Effect:

If all columns are specified (by the entry of * after SELECT), and a single database table is specified after FROM (rather than a view or a join expression), the addition PRIMARY KEY can be used to sort the resulting set in ascending order according to the content of the primary key of this database table.

The addition PRIMARY KEY cannot be specified if a view or a join expression is statically specified after FROM. If a view or a join expression is specified after FROM in the dynamic specification dbtab_syntax, the data is sorted by all columns of the resulting set.

Alternative 2

... ORDER BY {col1|a1} [ASCENDING|DESCENDING]
             {col2|a2} [ASCENDING|DESCENDING] ...

Effect:

For any column specifications after SELECT, a list of columns can be entered after ORDER BY, by which the resulting set should be sorted. Only columns that are listed after SELECT can be entered. Columns can be specified directly using the column names col1 col2 ..., or the alternative column names a1 a2 .... The latter is required if you want to sort by columns that are specified as aggregate expressions. When multiple database tables are accessed and a column name is not unique, the column must be identified using the column selector ~.

The additions ASCENDING and DESCENDING determine whether the rows are sorted in ascending or descendding order. If neither addition is specified, the sorg is performed in ascending order. The priority of sorting is based on the order in which the components col1 col2... or a1 a2 ... are specified.

Pooled and cluster tables cannot be sorted by all types of column. Columns specified after ORDER BY cannot be of the type LCHAR, LRAW, STRING, or RAWSTRING.

Note:

If single columns are specified in the addition ORDER BY, the statement SELECT bypasses the SAP buffering.

Alternative 3

... ORDER BY (column_syntax)

Effect:

As an alternative to static column specification, a bracketed data object column_syntax can be specified, which either contains the syntax of the list of columns or is initial when the statement is executed. The addition PRIMARY KEY cannot be specified in column_syntax. For column_syntax, the same applies as for the dynamic specification of columns after SELECT. If the content of column_syntax is initial, the addition ORDER BY is ignored.

Note:

For performance reasons, sorting should only be performed in tha databases system if the sort is supported by an index.

Example:

Selecting the database table SFLIGHT in a method, whereby the sort criterion is transferred as an input parameter. In this case, the user must enter the criterion using the correct syntax on the selection screen. In a proper application, you would normally prepare an input help using a selection list.

TYPES sflight_table_type TYPE TABLE OF sflight.
CLASS handle_sflight DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS select_sort_sflight
          IMPORTING sort_crit TYPE string
          EXPORTING sflight_tab TYPE sflight_table_type
                  RAISING cx_sy_dynamic_osql_error.
ENDCLASS.

PARAMETERS p_sort TYPE c LENGTH 40.
DATA: s_sort TYPE string,
      result_tab TYPE sflight_table_type.

TRY.
    s_sort = p_sort.
    handle_sflight=>select_sort_sflight(
      EXPORTING sort_crit = s_sort
      IMPORTING sflight_tab = result_tab ).
  CATCH cx_sy_dynamic_osql_error.
    MESSAGE `Wrong sort criterium!` TYPE 'I'.
ENDTRY.

CLASS handle_sflight IMPLEMENTATION.
  METHOD select_sort_sflight.
    SELECT *
           FROM sflight
           INTO TABLE sflight_tab
           ORDER BY (sort_crit).
  ENDMETHOD.
ENDCLASS.