CALL TRANSACTION ta { [AND SKIP FIRST SCREEN]
| [USING bdc_tab [bdc_options]] }.
1. ... AND SKIP FIRST SCREEN
2. ... USING bdc_tab [bdc_options]
The statement CALL TRANSACTION calls the transaction whose transaction code is contained in data object ta. The data object ta must be of character type and must contain the transaction code in uppercase letters. If the transaction specified in ta cannot be found, an untreatable exception is triggered. The additions suppress the display of the initial screen and allow you to execute the transaction using a batch input session.
At CALL TRANSACTION the calling program and its data is kept, and after exiting the called transaction, processing is resumed in the calling program after the call.
When the transaction is called, the ABAP program linked with the transaction code is loaded in a new internal session. The session of the calling program is kept. The called program runs in an SAP LUW of its own.
After the end of the transaction call, program execution of the calling program resumes after the CALL TRANSACTION statement.
At the statement CALL TRANSACTION, the authorization of
the current user to execute the called transaction is not checked automatically. If the calling program
does not execute a check, the called program must check the authorization. To do this, the called program must call function module AUTHORITY_CHECK_TCODE.
... AND SKIP FIRST SCREEN
This addition suppresses the display of a screen of the initial dynpro of a called dialog transaction. The addition AND SKIP FIRST SCREEN suppresses the first screen under these prerequisites:
If these prerequisites are met, that screen of the dynpro is displayed that is specified in the Screen Painter as the
next dynpro of the initial dynpro.
If the static next dynpro of the initial dynpro of the called dialog transaction FLIGHT_TA is not the initial dynpro itself, its screen is suppressed, because its input fields are filled using the SPA/GPA parameters CAR and CON.
DATA: carrid TYPE spfli-carrid,
connid TYPE spfli-connid.
...
SET PARAMETER ID: 'CAR' FIELD carrid,
'CON' FIELD connid.
CALL TRANSACTION 'FLIGHT_TA' AND SKIP FIRST SCREEN.
... USING bdc_tab [bdc_options]
Use this addition to pass an internal table bdc_tab of row type BDCDATA from the ABAP Dictionary to a dialog transaction. The additions bdc_options control the batch input processing. When a transaction with addition USING is called, the system field sy-binpt is set to value "X" in the called program - while this transaction is running, no other transaction can be called with this addition.
The internal table bdc_tab is the program-internal representation of a batch input session and must be filled accordingly. The structure BDCDATA has the components shown in the table below.
| Component | Description |
| PROGRAM | Name of the program of the called transaction |
| DYNPRO | Number of the dynpro to be processed |
| DYNBEGIN | Flag for the beginning of a new dynpro (possible values are "X" and " ") |
| FNAM | Name of a dynpro field to be filled or batch input control statement, for example, to position the cursor |
| FVAL | Value to be passed to the dynpro field or to the control statement |
Using the internal table bdc_tab, you can provide any number of screens of the called transaction with input and user actions.
System Fields
| sy-subrc | Description |
| 0 | The batch input processing of the called transaction was successful. |
| < 1000 | Error in the called transaction. If within the transaction a message was sent, you can receive it using the addition MESSAGES. |
| 1001 | Error in batch input processing. |
Outside of ABAP Objects you can specify the additions AND SKIP FIRST
SCREEN and USING together. However, this does
not make sense, because the addition AND SKIP FIRST SCREEN is desigend only to fill the mandatory input fields using
SPA/GPA parameters, while the
batch input table specified with USING controls the entire transaction flow including the display of the
screens.
Call of the Class Builder (transaction SE24) and display of class CL_SPFLI_PERSISTENT. The internal table bdcdata_tab contains the input for the batch input processing of the first dynpro (1000) of the transaction. Using structure opt, the batch input processing is set to suppress the first screen and to display the next screen in the standard size.
DATA class_name TYPE c LENGTH 30 VALUE 'CL_SPFLI_PERSISTENT'.
DATA: bdcdata_wa TYPE bdcdata,
bdcdata_tab TYPE TABLE OF bdcdata.
DATA opt TYPE ctu_params.
CLEAR bdcdata_wa.
bdcdata_wa-program = 'SAPLSEOD'.
bdcdata_wa-dynpro = '1000'.
bdcdata_wa-dynbegin = 'X'.
APPEND bdcdata_wa TO bdcdata_tab.
CLEAR bdcdata_wa.
bdcdata_wa-fnam = 'BDC_CURSOR'.
bdcdata_wa-fval = 'SEOCLASS-CLSNAME'.
APPEND bdcdata_wa TO bdcdata_tab.
CLEAR bdcdata_wa.
bdcdata_wa-fnam = 'SEOCLASS-CLSNAME'.
bdcdata_wa-fval = class_name.
APPEND bdcdata_wa TO bdcdata_tab.
CLEAR bdcdata_wa.
bdcdata_wa-fnam = 'BDC_OKCODE'.
bdcdata_wa-fval = '=CIDI'.
APPEND bdcdata_wa TO bdcdata_tab.
opt-dismode = 'E'.
opt-defsize = 'X'.
CALL TRANSACTION 'SE24' USING bdcdata_tab OPTIONS FROM opt.
Non-Catchable Exceptions